/*******************************************************************
*gelpict1.csm version 1.1									
*													
*													
*Script to set	camera to take a picture of EtBr stained gel.		
*	focus distance: 50 cm (18 inches)						
*	Exposure:	user selectable								
*	Aperture:	F/3 (300)									
*	Written for	Kodak DC290							
*													
*Author Jim Burnette, July 29, 2002 This is the completed script
*Copyright © James M. Burnette, III, 2002.
********************************************************************/


#required stuff: 
name "Gel Capture" 
mode 0 #capture mode 
menu "Picture Type"
label "Gel Capture" 

#end required stuff

#variables
declare i: status, uRawCnt
declare u: FOCDIST, uTakenCnt, uAvailCnt, shutter, choice, xmodnum

status = 0	#assume normal operation
xmodnum = 2 #default to long exposure mode
FOCDIST = 50	#set to 50 cm (1.5 ft), change to change distance
#find out if there's enough space 
status = GetStorageStatus(uTakenCnt, uAvailCnt, uRawCnt)

if uAvailCnt < 2
	DisplayLine ("Memory almost full.")
	DisplayLine ("Delete some images.") 
	Wait (500)
	goto Done 	
end

#Get Shutter Speed
DisplayLine ("Select shutter speed")
MenuLoop:
	SetOption (1, "1/4 sec.")
	SetOption (2, "1/2 sec.")
	SetOption (3, "3/4 sec.")
	SetOption (4, "1 sec.")
	SetOption (5, "1.5 sec.")
	SetOption (6, "2 sec.")
	SetOption (7, "Auto")
	GetOption (choice)

if choice == 0 
	goto MenuLoop 
end 
if choice == 1
	shutter = 250000
end
if choice == 2
	shutter = 500000 
end 
if choice == 3
	shutter = 750000 
end 
if choice == 4
	shutter = 1000000 
end
if choice == 5
	shutter = 1500000 
end 
if choice == 6
	shutter = 2000000 
end
if choice == 7
	xmodnum = 1
 shutter = 250000
end

#set the focus mode 
status = SetCameraState("fmod",3) 
if status != 0
	Alert("Unable to set to ","manual focus mode")
end

#set focus distance
status = SetCameraState("fdst",FOCDIST)	#Line 30
/* if status == 0
	Alert ("Focus Set")
	Wait(500)
end
*/
if status != 0
	Alert ("Unable to set focus!")
end

#set aperture f/3 = 300 Line 40 
status = SetCameraState("aper", 300) 
/* if status == 0
	Alert ("Aperature Set")
	Wait(500) 
end 
*/ 

if status != 0
	Alert ("Unable to set aperature")
	Wait(500) 
end 

#set shutter speed 500,000 = 0.5 sec. 
status = SetCameraState("xmod", xmodnum) 
if status != 0
	Alert ("xmod not set")
end 

status = SetCameraState("shut", shutter)
/*if status == 0
	Alert ("Shutter speed Set")
	Wait(500) 
end*/ 

if status != 0
	Alert ("Unable to set shutter!")
	Wait(500) 
end

#Ask for Zoom 

SetOption(1, "Set Zoom to 3x") 
SetOption(2, "No Zoom")
GetOption (choice) 
if choice == 2
	goto CenterFocus
end 

if choice == 1 
	#set zoom 
	status = SetCameraState("zmod", 2) 
	if status !=0
		Alert ("Unable to zmod!")
		Wait(500) 
	end
 	status = SetCameraState("zpos", 300) 
	if status != 0
		Alert ("Unable to set zpos!")
		Wait(500) 
	end
end

#set to center spot focus 
CenterFocus: 
status = SetCameraState("fmtd", 2) 
if status != 0
	Alert ("Unable to set fmtd!")
	Wait(500) 
end

Done:
DisplayLine("Take Picture")
#End of script
Wait(1)	#hack to prevent exit problems
exitscript

End of File